#### Template:
### Dumb -- no pass-through effect where heavy lifting is done by remote server
SELECT * WHERE {
		SERVICE <end-point-url> 
				{
					?s a ?o
				}

			} 
LIMIT 5

### Smart -- pass-through via sub query where heavy lifting is done by remote server
SELECT DISTINCT *
WHERE { SERVICE <end-point-url>
          {
                SELECT distinct *
                WHERE {?s a ?o.}
                LIMIT 5
         }
      }


### DBpedia
SELECT DISTINCT *
WHERE { SERVICE <http://dbpedia.org/sparql>
          {
                SELECT distinct *
                WHERE {?s a ?o.}
                LIMIT 5
         }
      }




## Sindice.com

SELECT DISTINCT *
WHERE { SERVICE <http://sparql.sindice.com/sparql>
          {
                SELECT distinct *
                WHERE {?s a ?o.}
                LIMIT 5
         }
      }


##Nature.com
SELECT DISTINCT *
WHERE { SERVICE <http://data.nature.com/sparql>
          {
                SELECT distinct *
                WHERE {?s a ?o.}
                LIMIT 5
         }
      }


### URIBURNER test
SELECT DISTINCT *
WHERE { SERVICE <http://uriburner.com/sparql>
          {
                SELECT distinct *
                WHERE {?s a ?o.}
                LIMIT 5
         }
      }
	  
SELECT DISTINCT *
WHERE { SERVICE <http://health.data.gov/sparql>
      {
            SELECT distinct *
            WHERE {?s a ?o.}
            LIMIT 5
     }
  }

## Nature.com 1

SELECT DISTINCT *
WHERE { SERVICE <http://data.nature.com/sparql>
        {
             SELECT ?doi ?title ?name
			 WHERE { ?doi dc:title ?title .
  	   				filter (regex(?title,"hydro","i")) .
  				  	?doi bibo:contributorList [ rdf:first [ foaf:name ?name ] ] .
				   } 
			LIMIT 25
       }
    }
	
## Nature.com 2

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX npg: <http://ns.nature.com/terms/>
PREFIX npgd: <http://ns.nature.com/datasets/>
PREFIX npgg: <http://ns.nature.com/graphs/>

SELECT DISTINCT *
WHERE { SERVICE <http://data.nature.com/sparql>
          {
		  SELECT ?article ?mesh 
		  WHERE
		  		{ 
				    ?article a npg:Article . 
				    ?article npg:hasRecord [ dc:subject ?mesh ] . 
				    filter regex(?mesh, "blood", "i") 
		  		} 
		  LIMIT 25              
         }
      }

## Nature.com SPARUL
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX npg: <http://ns.nature.com/terms/>
PREFIX npgd: <http://ns.nature.com/datasets/>
PREFIX npgg: <http://ns.nature.com/graphs/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sc: <http://purl.org/science/owl/sciencecommons/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX void: <http://rdfs.org/ns/void#>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX bibo: <http://purl.org/ontology/bibo/>

INSERT INTO <urn:data:sparql:fed:data:test> { ?doi dc:title ?title ; foaf:name ?name }
WHERE { SERVICE <http://data.nature.com/sparql>          
		 {
         SELECT ?doi ?title ?name
         WHERE {
                    ?doi dc:title ?title .
			        FILTER (regex(?title,"hydro","i")) .
			        ?doi bibo:contributorList [ rdf:first [ foaf:name ?name ] ] .
         		}              
		 LIMIT 25         
		 }      
	};
						 
 
## health.data.gov
#######################################
#
# Retrieve all clinical quality averages for the US
#
# This query fetches descriptions for conditionId, measureId, metricId
#
#######################################
#
PREFIX gd: <http://reference.data.gov/def/govdata/>
PREFIX hoco: <http://health.data.gov/def/hospital-compare/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX comp: <http://health.data.gov/def/compare/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
SELECT *
WHERE
   { SERVICE <http://health.data.gov/sparql>
           {
             SELECT DISTINCT ?record ?date ?condition ?measure ?metric ?percentage ?ratio ?medianTime
         					 ?nationalCount ?msdrg ?footnote ?conditionId ?measureId ?metricId ?footnoteId 
             WHERE { <http://reference.data.gov/id/country/US> hoco:recordset _:rs.
      				GRAPH ?g { _:rs hoco:record ?record . }
      				?g dcterms:issued ?date.
      				OPTIONAL { ?record comp:condition ?conditionId. 
							   ?conditionId rdfs:comment ?condition. }
      				OPTIONAL { ?record comp:measure ?measureId. 
							   ?measureId rdfs:comment ?measure. }
      				OPTIONAL { ?record comp:metric ?metricId. 
							   ?metricId rdfs:comment ?metric. }
      			    OPTIONAL { ?record gd:percentage ?percentage. }
			        OPTIONAL { ?record hoco:ratio ?ratio. }
			        OPTIONAL { ?record hoco:medianTime ?medianTime. }
			        OPTIONAL { ?record hoco:nationalCount ?nationalCount. }
			        OPTIONAL { ?record hoco:msdrg ?msdrg. }
			       OPTIONAL { ?record comp:footnote ?footnoteId. ?footnoteId rdfs:comment ?footnote. }
		         }
			 LIMIT 100
		   }
   }


##Patriots
SELECT * WHERE { SERVICE <http://lod.openlinksw.com/sparql>
{{
SELECT DISTINCT *  FROM <http://dbpedia.org> WHERE {?x a <http://dbpedia.org/ontology/AmericanFootballPlayer> ; 
                                 
                                 dbpedia-owl:activeYearsStartYear ?startYear;
                                 <http://purl.org/dc/terms/subject> <http://dbpedia.org/resource/Category:New_England_Patriots_players>;
                                 dbpprop:draftpick		?draftPic;
                                 dbpedia-owl:position	?position;
                                 dbpedia-owl:number	?number;	
                                 dbpedia-owl:draftRound ?draftRound;	
                                 dbpedia-owl:draftPick ?draftPick.
                                 optional {?x dbpedia-owl:activeYearsEndYear	 ?endYear} .
                                 optional {?x dbpprop:finalyear ?finalYear}.
}
}}
}
## Bio Ontology Portal
## Mulgara based SPARQL Endpoint

SELECT  ?g ?label ?versionId ?virtualId ?format
WHERE { SERVICE <http://sparql.bioontology.org/sparql/>
              {{ 
				SELECT ?graphURI ?label ?versionId ?virtualId ?format
				WHERE {
 						GRAPH ?g {
   						  	   ?s <http://purl.bioontology.org/ontology/bioportal/displayLabel> ?label .
							   ?s <http://purl.bioontology.org/ontology/bioportal/id> ?versionId .
							   ?s <http://purl.bioontology.org/ontology/bioportal/ontologyId> ?virtualId .
							   ?s <http://purl.bioontology.org/ontology/bioportal/format> ?format
 							}
						}
             	}}
		}


##RPI
## Tweaked re. problem variables and geopoints (?latitude and ?longitude)

PREFIX dgp32:  <http://data-gov.tw.rpi.edu/vocab/p/32/>
PREFIX xsd:  <http://www.w3.org/2001/XMLSchema#> 
SELECT *
WHERE { SERVICE <http://data-gov.tw.rpi.edu/sparql>
          {{
SELECT *
#FROM NAMED <http://data-gov.tw.rpi.edu/raw/34/data-34.rdf>
#WHERE {  GRAPH <http://data-gov.tw.rpi.edu/raw/34/data-34.rdf>{
WHERE {  
			GRAPH <http://data-gov.tw.rpi.edu/vocab/Dataset_34>
				{
         		 ?s dgp32:eqid ?ad. 
		         ?s dgp32:eqid ?label. 
		         ?s dgp32:region ?region.
		         ?s dgp32:datetime ?datetime. 
			     ?s dgp32:magnitude ?magnitude.
		         ?s dgp32:depth ?depth. 
		         ?s dgp32:lat ?latitude.
		         ?s dgp32:lon ?longitude. 
		         ?s dgp32:src ?src.
		         filter ( xsd:float(?magnitude) >= 3 && xsd:float(?depth) <= 50 )
        		}
		}
	}}
}

##Problem Query re. SPARQL+CXML special variables
PREFIX dgp32:  <http://data-gov.tw.rpi.edu/vocab/p/32/>
PREFIX xsd:  <http://www.w3.org/2001/XMLSchema#> 
SELECT ?id ?label ?datetime  ?lat ?lon ?magnitude ?depth  ?region ?src ?uri 
WHERE { service <http://data-gov.tw.rpi.edu/sparql>
          {{
SELECT ?id ?label ?datetime  ?lat ?lon ?magnitude ?depth  ?region ?src ?uri 
#FROM NAMED <http://data-gov.tw.rpi.edu/raw/34/data-34.rdf>
#WHERE {  GRAPH <http://data-gov.tw.rpi.edu/raw/34/data-34.rdf>{
WHERE {  
			GRAPH <http://data-gov.tw.rpi.edu/vocab/Dataset_34>
				{
         		 ?uri dgp32:eqid ?id. 
		         ?uri dgp32:eqid ?label. 
		         ?uri dgp32:region ?region.
		         ?uri dgp32:datetime ?datetime. 
			     ?uri dgp32:magnitude ?magnitude.
		         ?uri dgp32:depth ?depth. 
		         ?uri dgp32:lat ?lat.
		         ?uri dgp32:lon ?lon. 
		         ?uri dgp32:src ?src.
		         filter ( xsd:float(?magnitude) >= 3 && xsd:float(?depth) <= 50 )
        		}
		}
	}}
}
##GeoSpecies

PREFIX foaf:  <http://xmlns.com/foaf/0.1/>
PREFIX txn:  <http://lod.taxonconcept.org/ontology/txn.owl#>
PREFIX rdf:  <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX dbpedia_owl: <http://dbpedia.org/ontology/>


select distinct ?s as ?href ?order ?sciname ?authority ?cname ?year ?o as ?image ?aligned 
where { service <http://virtuoso.taxonconcept.org/sparql>
          {{

                select distinct ?s ?order ?sciname ?authority ?cname ?year ?o ?aligned
                where {
                            ?s rdf:type txn:SpeciesConcept.
                          ?s txn:inDBpediaClade dbpedia_owl:Mammal.
                          ?s foaf:depiction  ?o.
                          ?s txn:hasScientificName ?sciname.
                          optional {?s umbel:isAligned ?aligned}.
                          optional {?s txn:inCoLOrder ?order}.
                          optional {?s txn:yearDescribed ?year}.
                          optional {?s txn:commonName ?cname}.
                          optional {?s txn:scientificNameAuthorship ?authority}.
						  filter (lang(?authority) = "en") .
                    }
                limit 1000

         }}
      }


##DBpedia Graph on LOD

SELECT *
WHERE
    { SERVICE <http://lod.openlinksw.com/sparql>
            {{
            SELECT DISTINCT *
		              WHERE
		                    {
		                        ?href a dbpedia-owl:Person;
		                                rdfs:label ?name.
		                         OPTIONAL {?href foaf:depiction ?qrcode} .
		                         ?href rdfs:comment ?description.
		                         ?description bif:contains "CEO".
		                         FILTER (lang(?description) = "en")
								 FILTER (lang(?name) = "en")

		                    }
		              LIMIT 100
               }}
       
    }

##Data.Gov.UK
## LOD endpoint

SELECT *
WHERE
    { SERVICE <http://lod.openlinksw.com/sparql>
            {{
             SELECT *
              WHERE
                    {
                          ?s a <http://education.data.gov.uk/def/school/School> .
                        ?s <http://www.w3.org/2000/01/rdf-schema#label> ?label .
                        ?s <http://www.w3.org/2003/01/geo/wgs84_pos#lat> ?lat .
                        ?s <http://www.w3.org/2003/01/geo/wgs84_pos#long> ?long .
                    }
              LIMIT 10
               }}
       
    }

## Data.Gov.UK
##Talis Endpoint

SELECT *
WHERE
    { SERVICE <http://services.data.gov.uk/education/sparql>
        {
            { SELECT *
              WHERE
                    {
                          ?s a <http://education.data.gov.uk/def/school/School> .
                        ?s ?p ?o.
                    }
              LIMIT 10
               }
        }
    }
   
##Talis Endpoint

SELECT *
WHERE
    { SERVICE <http://services.data.gov.uk/education/sparql>
            {{
             SELECT *
              WHERE
                    {
                        ?s a <http://education.data.gov.uk/def/school/School> .
                        ?s <http://www.w3.org/2000/01/rdf-schema#label> ?label .
                        ?s <http://www.w3.org/2003/01/geo/wgs84_pos#lat> ?lat .
                        ?s <http://www.w3.org/2003/01/geo/wgs84_pos#long> ?long .
						?s <http://education.data.gov.uk/def/school/address> ?addr.
                        optional {?s <http://education.data.gov.uk/def/school/gender> ?gender}.
		        		optional {?s <http://education.data.gov.uk/def/school/religiousCharacter> ?religion}.
						optional {?s <http://education.data.gov.uk/def/school/typeOfEstablishment> ?type}.
						optional {?s <http://education.data.gov.uk/def/school/uniqueReferenceNumber> ?refNo}.
						optional {?s </http://education.data.gov.uk/def/school/establishmentNumber> ?estabNo}.
                        ?addr <http://education.data.gov.uk/def/school/address1> ?addr1 .
						?addr <http://education.data.gov.uk/def/school/address2> ?addr2.
						?addr <http://education.data.gov.uk/def/school/postcode> ?postcode.
						?addr <http://education.data.gov.uk/def/school/town> ?town.
					
	           		}
              LIMIT 200
             }}
       
    }


##Data.Gov.UK's Talis Endpoint + Virtuoso SPARQL (using custom default image for CXML) based PivotViewer Page
## Note: (<http://www.kingslon.co.uk/Images/students_new.jpg>) as ?image
## Used to set default Pivot Tiles Image

SELECT ?s as ?href ?gender ?religion ?name ?lat 
       ?long ?addr ?addr1 ?addr2 ?postcode ?town ?estabNo ?refNo ?type 
       (<http://www.kingslon.co.uk/Images/students_new.jpg>) as ?image
WHERE
    { SERVICE <http://services.data.gov.uk/education/sparql>
            {
             SELECT *
              WHERE
                    {
                        ?s a <http://education.data.gov.uk/def/school/School> .
                        ?s <http://www.w3.org/2000/01/rdf-schema#label> ?name.
                        ?s <http://www.w3.org/2003/01/geo/wgs84_pos#lat> ?lat .
                        ?s <http://www.w3.org/2003/01/geo/wgs84_pos#long> ?long .
						?s <http://education.data.gov.uk/def/school/address> ?addr.
                        OPTIONAL {?s <http://education.data.gov.uk/def/school/gender> ?gender}.
				        OPTIONAL {?s <http://education.data.gov.uk/def/school/religiousCharacter> ?religion}.
						OPTIONAL {?s <http://education.data.gov.uk/def/school/typeOfEstablishment> ?type}.
						OPTIONAL {?s <http://education.data.gov.uk/def/school/uniqueReferenceNumber> ?refNo}.
						OPTIONAL {?s </http://education.data.gov.uk/def/school/establishmentNumber> ?estabNo}.
                        ?addr <http://education.data.gov.uk/def/school/address1> ?addr1 .
						?addr <http://education.data.gov.uk/def/school/address2> ?addr2.
						?addr <http://education.data.gov.uk/def/school/postcode> ?postcode.
						?addr <http://education.data.gov.uk/def/school/town> ?town.
					
	           		 }
              LIMIT 200
             }
       
    }

##Data.Gov.UK
## TSO (Garlik)
PREFIX naptan: <http://transport.data.gov.uk/def/naptan/>

SELECT *
WHERE
    { SERVICE <http://gov.tso.co.uk/transport/sparql>
            {{
             SELECT *
              WHERE
                   
	{
       ?stop naptan:administrativeArea <http://transport.data.gov.uk/id/administrative-area/104> ;
	naptan:street ?street ;
	naptan:naptanCode ?code	
	}
                    
              LIMIT 10
               }}
       
    }

## TSO (Garlik)
PREFIX naptan: <http://transport.data.gov.uk/def/naptan/>

SELECT *
WHERE
    { SERVICE <http://gov.tso.co.uk/transport/sparql>
            {{
             SELECT *
              WHERE
                   
	{
      ?stop naptan:administrativeArea <http://transport.data.gov.uk/id/administrative-area/104> ;
	naptan:street ?street ;
	naptan:naptanCode ?code		
	}
                    
              LIMIT 100
               }}
       
    }

##TSO (Garlik)
##Legislation

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX dct: <http://purl.org/dc/terms/>

SELECT *
WHERE
    { SERVICE <http://gov.tso.co.uk/legislation/sparql>
            {
             SELECT *
              WHERE
                   
					{
				      	?work a frbr:Work .
				 		?work dct:title ?description .
				 		?work dct:created ?date .
						?work dct:subject ?subject.
						?work dct:valid ?valid.
						?work rdfs:label ?name.
						optional {?work foaf:depiction ?image}.
				 		FILTER (?date >= "2010-10-15"^^xsd:date)	
					}
                    
              LIMIT 100
               }
     }


##Open University UK
SELECT *
WHERE
    { SERVICE <http://data.open.ac.uk/query>
            {{
           SELECT distinct ?x ?title ?description 
			WHERE {
					?x <http://data.open.ac.uk/podcast/ontology/relatesToCourse> <http://data.open.ac.uk/course/t209>.
					?x <http://purl.org/dc/terms/title> ?title.
					?x <http://www.w3.org/TR/2010/WD-mediaont-10-20100608/description> ?description 
				   } 
			LIMIT 10 
               }}
     }

##OpenEI (US Govt -- Energy Dept.)
## SPARQL-FED OpenEI

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX swivt: <http://semantic-mediawiki.org/swivt/1.0#>
PREFIX resource: <http://openei.org/resources/>
PREFIX category: <http://openei.org/resources/Category-3A>
PREFIX property: <http://openei.org/resources/Property-3A>

SELECT *
WHERE
    { SERVICE <http://en.openei.org/sparql>
            {{
             SELECT *
              WHERE
                    {
                          ?organization swivt:page ?page.
                          ?organization property:Region resource:Bay_Area.
                        ?organization rdfs:label ?name.
                          OPTIONAL { ?organization foaf:depiction ?image}.
                          OPTIONAL { ?organization property:Address ?address. }.
                          OPTIONAL { ?organization property:Zip ?zip. }.
                          OPTIONAL { ?organization property:Coordinates ?coordinates. }.
                          OPTIONAL {
                            ?organization property:Place ?place.
                            ?place rdfs:label ?placename.}.
                          OPTIONAL {
                            ?organization property:Sector ?sector.
                            ?sector rdfs:label ?sectorname.}.
                          OPTIONAL {
                            ?organization rdf:type ?category.
                            ?category rdfs:label ?categoryname.}.
                    }
              LIMIT 100
               }}
       
    }

##OpenEI 2

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX swivt: <http://semantic-mediawiki.org/swivt/1.0#>
PREFIX resource: <http://en.openei.org/lod/resource/wiki/>
PREFIX category: <http://en.openei.org/lod/resource/wiki/Category-3A>
PREFIX property: <http://en.openei.org/lod/resource/wiki/Property-3A>
PREFIX fprop: <http://en.openei.org/lod/resource/wiki/Property-3AFile-2F>

SELECT ?map ?image as ?qrcode ?image ?extent ?placeName ?author
WHERE {
  		SERVICE <http://en.openei.org/sparql> 
		{{
    		SELECT DISTINCT ?image ?extent ?placeName ?author ?map
    		WHERE {
      				?map rdf:type category:Map_Image_Files.
      				?map foaf:depiction ?image.
      				OPTIONAL {?map property:Place ?place.
        					  ?place rdfs:label ?placeName.
						      }.
      				OPTIONAL { ?map fprop:GeographicExtent ?extent. }.
				    OPTIONAL { ?map fprop:Author ?author. }.
				   } 
			LIMIT 1000
		  }}
		}


##Reegle.info
##European Green Energy Data Space

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX reegle: <http://reegle.info/schema#>
PREFIX dbpedia-prop: <http://dbpedia.org/property/>

SELECT *
WHERE
    { SERVICE <http://sparql.reegle.info/>
            {
				SELECT DISTINCT *
				WHERE {
						?actor a foaf:Organization;
						dcterms:subject <http://reegle.info/categories/12>;
					    foaf:name ?name. FILTER (lang(?name) = "en" ).
					    ?actor foaf:depiction ?image.
					    optional {?actor foaf:mbox ?mbox}.
						optional {?actor foaf:homepage ?homepage}.
						optional {?actor foaf:phone ?phone}.
					    optional {?actor dcterms:subject ?subject}.
                        optional {?actor reegle:mission ?mission}.
						optional {?actor reegle:activities ?activities}.
						optional {?actor reegle:activeIn ?activeIn}.			          
                        optional {?actor foaf:depiction ?image}.
						optional {?actor reegle:mission ?mission}.
						optional {?actor dbpedia-prop:street ?street}.
						optional {?actor dbpedia-prop:city ?location}.
						optional {?actor dbpedia-prop:state ?state}.
						optional {?actor dbpedia-prop:abbreviation ?short}.
						optional {?actor dbpedia-prop:zipCode ?zip}.
					  }
				LIMIT 50
			}
     }
##Punkt
##PoolParty Endpoint

PREFIX skos:<http://www.w3.org/2004/02/skos/core#>

SELECT *
WHERE
    { SERVICE <http://open.poolparty.punkt.at/PoolParty/SPARQLEndPoint/urn:uuid:1D763C7B-F7F6-0001-7A36-93201D7016CC>
            {{
             SELECT *
              WHERE
                   
				{ 
         		 ?Concept a skos:Concept.
		         ?Concept skos:prefLabel ?prefLabel . 

        		}
         	 limit 100    
			}}
       
    }

## DBpedia

SELECT *
FROM <http://g1> 
FROM NAMED <http://dbpedia.org>
WHERE {
       ?s a <http://sample-type> .
       SERVICE <http://dbpedia.org/sparql> (in ?s) 
            {
        		graph <http://dbpedia.org> 
					{ ?s ?p ?o .
            		  filter (?p != <http://dbpedia.org/property/abstract>)
					}
			}
		OPTIONAL { ?p rdfs:label ?lbl }
	  }

##DBpedia
## Movie DB
PREFIX movie: <http://data.linkedmdb.org/resource/movie/>
PREFIX dbpedia: <http://dbpedia.org/ontology/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?actor_name ?birth_date

WHERE {
  SERVICE <http://data.linkedmdb.org/sparql> {{
    <http://data.linkedmdb.org/resource/film/675> movie:actor ?actor .
    ?actor movie:actor_name ?actor_name
  }}
  SERVICE <http://dbpedia.org/sparql> {{
    ?actor2 a dbpedia:Actor ; foaf:name ?actor_name_en ; dbpedia:birthDate ?birth_date .
    FILTER(STR(?actor_name_en) = ?actor_name)
  }}
}